BinaryEye/app/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'

android {
	compileSdkVersion sdk_version
	buildToolsVersion build_tools_version

	defaultConfig {
		minSdkVersion 9
		targetSdkVersion sdk_version

		versionCode 24
		versionName '1.7.2'

		// it's recommended to set this value to the lowest API level
		// able to provide all the functionality
		renderscriptTargetApi 24
		renderscriptSupportModeEnabled true

		testInstrumentationRunner 'android.support.test.runner.AndroidJUnitRunner'
	}

	signingConfigs {
		config {
			keyAlias System.getenv('ANDROID_KEY_ALIAS')
			keyPassword System.getenv('ANDROID_KEY_PASSWORD')
			storePassword System.getenv('ANDROID_STORE_PASSWORD')
			def filePath = System.getenv('ANDROID_KEYFILE')
			storeFile filePath ? file(filePath) : null
		}
	}

	sourceSets {
		main.java.srcDirs += 'src/main/kotlin'
		androidTest.java.srcDirs += 'src/androidTest/kotlin'
	}

	buildTypes {
		debug {
			applicationIdSuffix '.debug'
		}

		release {
			proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
			minifyEnabled true
			shrinkResources true
			signingConfig signingConfigs.config
		}
	}

	lintOptions {
		// because at the time of writing, even the latest version
		// of RenderScript is raising this error no matter if
		// renderscriptTargetApi matches targetSdkVersion
		disable 'GradleCompatible'
	}
}

dependencies {
	androidTestImplementation ('com.android.support.test:runner:1.0.2') {
		exclude module: 'support-annotations'
	}
	androidTestImplementation ('com.android.support.test:rules:1.0.2') {
		exclude module: 'support-annotations'
	}
	testImplementation 'junit:junit:4.12'

	implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
	implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.0.1"
	implementation "com.android.support:appcompat-v7:$support_version"
	implementation "com.android.support:design:$support_version"
	implementation 'com.google.zxing:core:3.3.3'
	implementation 'com.github.markusfisch:CameraView:1.8.3'
}